home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Ahoy 1985 June
/
Ahoy_Magazine_85-06_1985_Double_L.d64
/
screen dump i
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
938b
|
34 lines
1 rem before loading this program you must poke44,64:poke16384,0:new
20 b=8192 :poke53272,24
25 poke 53265,peek(53265) or 32
30 for i=0 to 7999 : poke b+i,0 : next
40 for j=1024 to 2043 :pokej,1:next
100 for x = 0 to 319 step .4
105 y=int(100-(100*cos(x/05))*exp(-x/240))
150 char=int(x/8)
155 row=int(y/8)
160 line=y and 7
165 byte = b + row*320 + char*8 + line
170 bit=7-(x and 7)
175 poke byte,peek (byte) or (2^bit)
180 next x
190 get a$: if a$<>chr$(133) then 190
205 open4,4,5:cmd4:print chr$(10) chr$(10)
210 print chr$(27)"@":print chr$(27) chr$(51) chr$(16)
215 print" ";
220 print"------------------------------------------------------"chr$(10)
225 forl=0 to 24:print chr$(27) chr$(76) chr$(249) chr$(2);
230 for i=1 to 119:print chr$(0);:nexti:print chr$(245);
235 for cr = 0 to 39:
240 for p = 0 to 7:pbyt=0:e=2^(7-p)
245 for lc = 0 to 7
250 pbyt = pbyt-((peek(b+lc) and e)>0)*2^(7-lc)
255 next lc: print chr$(pbyt) chr$(pbyt);
260 next p : b=b+8
265 next cr: print chr$(245) chr$(10);
270 next l:print chr$(27)"@"
275 print" ";
280 print"------------------------------------------------------"
285 print#4,:close4
290 end